cell/internal/bootstrap.cm

// Hidden vars come from env:
//   CLI mode (cell_init):       os, args, core_path, shop_path, use_mcode
//   Actor spawn (script_startup): os, json, nota, wota, actorsym, init, core_path, shop_path
// args[0] = script name, args[1..] = user args
var load_internal = os.load_internal
function use_embed(name) {
  return load_internal("js_" + name + "_use")
}

var fd = use_embed('fd')
var json = use_embed('json')

var use_cache = {}
use_cache['fd'] = fd
use_cache['os'] = os
use_cache['json'] = json

// Bootstrap: load tokenize.cm, parse.cm, fold.cm from pre-compiled mach bytecode
function use_basic(path) {
  if (use_cache[path])
    return use_cache[path]
  var result = use_embed(replace(path, '/', '_'))
  use_cache[path] = result
  return result
}

// Load a module from .mach bytecode, falling back to .ast.json
function boot_load(name, env) {
  var mach_path = core_path + '/' + name + ".mach"
  var data = null
  if (fd.is_file(mach_path)) {
    data = fd.slurp(mach_path)
    return mach_load(data, env)
  }
  var ast_path = core_path + '/' + name + ".ast.json"
  data = text(fd.slurp(ast_path))
  return mach_eval_ast(name, data, env)
}

var boot_env = {use: use_basic}
var tokenize_mod = boot_load("tokenize", boot_env)
var parse_mod = boot_load("parse", boot_env)
var fold_mod = boot_load("fold", boot_env)

// Optionally load mcode compiler module
var mcode_mod = null
if (use_mcode) {
  mcode_mod = boot_load("mcode", boot_env)
}

// Warn if any .cm source is newer than its .mach bytecode
function check_mach_stale() {
  var pairs = [
    ["tokenize.cm", "tokenize.mach"],
    ["parse.cm", "parse.mach"],
    ["fold.cm", "fold.mach"],
    ["mcode.cm", "mcode.mach"],
    ["internal/bootstrap.cm", "internal/bootstrap.mach"],
    ["internal/engine.cm", "internal/engine.mach"]
  ]
  var stale = []
  var _i = 0
  var cm_path = null
  var mach_path = null
  var cm_stat = null
  var mach_stat = null
  while (_i < length(pairs)) {
    cm_path = core_path + '/' + pairs[_i][0]
    mach_path = core_path + '/' + pairs[_i][1]
    if (fd.is_file(cm_path) && fd.is_file(mach_path)) {
      cm_stat = fd.stat(cm_path)
      mach_stat = fd.stat(mach_path)
      if (cm_stat.mtime > mach_stat.mtime) {
        push(stale, pairs[_i][0])
      }
    }
    _i = _i + 1
  }
  if (length(stale) > 0) {
    print("warning: bytecode is stale for: " + text(stale, ", ") + "\n")
    print("run 'make regen' or './cell --core . regen.cm' to update\n")
  }
}
check_mach_stale()

// analyze: tokenize + parse, check for errors
function analyze(src, filename) {
  var tok_result = tokenize_mod(src, filename)
  var ast = parse_mod(tok_result.tokens, src, filename, tokenize_mod)
  var _i = 0
  var prev_line = -1
  var prev_msg = null
  var e = null
  var msg = null
  var line = null
  var col = null
  var has_errors = ast.errors != null && length(ast.errors) > 0
  if (has_errors) {
    while (_i < length(ast.errors)) {
      e = ast.errors[_i]
      msg = e.message
      line = e.line
      col = e.column
      if (msg != prev_msg || line != prev_line) {
        if (line != null && col != null) {
          print(`${filename}:${text(line)}:${text(col)}: error: ${msg}`)
        } else {
          print(`${filename}: error: ${msg}`)
        }
      }
      prev_line = line
      prev_msg = msg
      _i = _i + 1
    }
    disrupt
  }
  ast = fold_mod(ast)
  return ast
}

// Run AST through either mcode or mach pipeline
function run_ast(name, ast, env) {
  var compiled = null
  if (use_mcode) {
    compiled = mcode_mod(ast)
    return mcode_run(name, json.encode(compiled), env)
  }
  return mach_eval_ast(name, json.encode(ast), env)
}

// use() with ƿit pipeline for .cm modules
function use_fn(path) {
  var file_path = path + '.cm'
  var script = null
  var ast = null
  var result = null
  if (use_cache[path])
    return use_cache[path]

  // Check CWD first, then core_path
  if (!fd.is_file(file_path))
    file_path = core_path + '/' + path + '.cm'

  if (fd.is_file(file_path)) {
    script = text(fd.slurp(file_path))
    ast = analyze(script, file_path)
    result = run_ast(path, ast, {use: use_fn})
    use_cache[path] = result
    return result
  }

  // Fallback to embedded C module
  result = use_embed(replace(path, '/', '_'))
  use_cache[path] = result
  return result
}

// Helper to load engine.cm and run it with given env
function load_engine(env) {
  var engine_path = core_path + '/internal/engine.mach'
  var data = null
  var engine_src = null
  var engine_ast = null
  if (fd.is_file(engine_path)) {
    data = fd.slurp(engine_path)
    return mach_load(data, env)
  }
  engine_path = core_path + '/internal/engine.cm'
  engine_src = text(fd.slurp(engine_path))
  engine_ast = analyze(engine_src, engine_path)
  return run_ast('engine', engine_ast, env)
}

// Detect mode and route
// CLI mode has 'args'; actor spawn mode has 'init'
var program = null
var user_args = []
var _j = 0
var script_file = null
var script = null
var ast = null

if (args != null) {
  // CLI mode — run script directly
  program = args[0]
  _j = 1
  while (_j < length(args)) {
    push(user_args, args[_j])
    _j = _j + 1
  }

  script_file = program
  if (!ends_with(script_file, '.ce') && !ends_with(script_file, '.cm'))
    script_file = program + '.cm'

  // Search CWD then core_path, trying .cm then .ce
  if (!fd.is_file(script_file))
    script_file = core_path + '/' + program + '.cm'
  if (!fd.is_file(script_file))
    script_file = program + '.ce'
  if (!fd.is_file(script_file))
    script_file = core_path + '/' + program + '.ce'

  script = text(fd.slurp(script_file))
  ast = analyze(script, script_file)
  run_ast(program, ast, {use: use_fn, args: user_args, json: json})
} else {
  // Actor spawn mode — load engine.cm with full actor env
  load_engine({
    os: os, actorsym: actorsym, init: init,
    core_path: core_path, shop_path: shop_path, json: json, nota: nota, wota: wota,
    analyze: analyze, run_ast_fn: run_ast
  })
}